CFLib.org – Common Function Library Project

Description:
This function will return the length of a file. It uses the standard Java File object, which makes it very fast under ColdfusionMX. If a directory is passed instead of a file, the UDF will return the total size of all files in the directory. If the file or folder does not exist, it will return 0.

Return Values:
Returns a number.

Example:

<cfset filename="c:\autoexec.bat">
<cfoutput>
	Length: #fileSize(filename)#<br>
</cfoutput>

Parameters:

Full UDF Source:

<cfscript>
/**
 * This function will return the length of a file or a directory.
 * Version 2 by Nathan Dintenfass
 * Version 3 by Nat Papovich
 * 
 * @param filename 	 The filename or directory path. (Required)
 * @return Returns a number. 
 * @author Jesse Houwing (&#106;&#46;&#104;&#111;&#117;&#119;&#105;&#110;&#103;&#64;&#115;&#116;&#117;&#100;&#101;&#110;&#116;&#46;&#117;&#116;&#119;&#101;&#110;&#116;&#101;&#46;&#110;&#108;) 
 * @version 3, July 11, 2006 
 */
function fileSize(pathToFile) {
	var fileInstance = createObject("java","java.io.File").init(toString(arguments.pathToFile));
	var fileList = "";
	var ii = 0;
	var totalSize = 0;

	//if this is a simple file, just return it's length
	if(fileInstance.isFile()){
	    return fileInstance.length();
	}
	else if(fileInstance.isDirectory()) {
		fileList = fileInstance.listFiles();
		for(ii = 1; ii LTE arrayLen(fileList); ii = ii + 1){
		    totalSize = totalSize + fileSize(fileList[ii]);
		}
		return totalSize; 
	}
	else
		return 0;
}
</cfscript>