CFLib.org – Common Function Library Project

Description:
Function to set or clear a Windows file attribute (ReadOnly, Hidden, etc) for the specified file. This is essentially just a wrapper around the Scripting.FileSystemObject's File.Attribute property. It will work only on Windows systems.

Return Values:
Returns a Boolean value indicating whether the attribute was set.

Example:

<CFSET x = SetFileAttribute("c:\winnt\notepad.exe", "Archive", "No")>

<CFOUTPUT>
Was the attribute set? #YesNoFormat(x)#
</CFOUTPUT>

Parameters:

Full UDF Source:

<cfscript>
/**
 * Function to set or clear a Windows file attribute (ReadOnly, Hidden, etc) for the specified file.
 * Uses COM. This is a Windows only funciton. Requires CFOBJECT be enabled in the CF Administrator.
 * 
 * @param sFilePath 	 Absolute or relative path to the specified file. 
 * @param sAttribute 	 Attribute you wish to set.  Options are: ReadOnly, Hidden, System, Archive. 
 * @param bOnOff 	 Boolean value indicating whether the attribute should be on (Yes) or off (No). 
 * @return Returns a Boolean value indicating whether the attribute was set. 
 * @author Nate Weiss (&#110;&#97;&#116;&#101;&#64;&#110;&#97;&#116;&#101;&#119;&#101;&#105;&#115;&#115;&#46;&#99;&#111;&#109;) 
 * @version 1, September 27, 2001 
 */
function SetFileAttribute(sFilePath, sAttribute, bOnOff) {
   var result = False;
   var fso = 0;
   var f = 0;
   var iListPosition = 0;
   var iFlagPosition = 0;
   
   if ( FileExists(sFilePath) ) {
     fso = CreateObject("COM", "Scripting.FileSystemObject");
     f = fso.GetFile(sFilePath);
     iListPosition = ListFindNoCase("ReadOnly,Hidden,System,Archive", sAttribute);
     
     if (iListPosition GT 0) {
       iFlagPosition = ListGetAt("0,1,2,5", iListPosition);
       f.attributes = BitMaskSet(f.attributes, IIF(bOnOff, 1, 0), iFlagPosition, 1);
       result = True;
     }
   }
  
   return result;
 }
</cfscript>