CFLib.org – Common Function Library Project

Description:
This is a quick way to change all FORM variables into hidden fields in another form. It is particularly useful in multi-step forms where you want to pass things on from previous forms in the current form.

Return Values:
Returns a string.

Example:

<cfset form.test = 2>
<cfset form.foo = 1>
<cfoutput>
#htmlCodeFormat(formToHidden("gogoSubmit"))#
</cfoutput>

Parameters:

Full UDF Source:

<cfscript>
/**
 * Converts the Form structure to hidden form fields.
 * 
 * @param excludeList 	 A list of keys not to copy from the Form scope. Defaults to, and always includes, FIELDNAMES. 
 * @return Returns a string. 
 * @author Nathan Dintenfass (&#110;&#97;&#116;&#104;&#97;&#110;&#64;&#99;&#104;&#97;&#110;&#103;&#101;&#109;&#101;&#100;&#105;&#97;&#46;&#99;&#111;&#109;) 
 * @version 1, March 11, 2002 
 */
function formToHidden(){
	//a variable for iterating
	var key = "";
	//should we exlude any?  by default, no
	var excludeList = "FIELDNAMES";
	//a variable to return stuff
	var outVar = "";
	//if there is an argument, it is a list to exclude
	if(arrayLen(arguments))
		excludeList = excludeList & "," & arguments[1];
	//now loop through the form scope and make hidden fields
	for(key in form){
		if(NOT listFindNoCase(excludeList,key))
			outVar = outVar & "<input type=""hidden"" name=""" & key & """ value=""" & htmlEditFormat(form[key]) & """>";
	}
	return outVar;		
}
</cfscript>