CFLib.org – Common Function Library Project

Description:
This function when passed an assertion rule string will validate assertions given, which enables the user to parse multiple variables against multiple rule sets.

Return Values:
Returns a Boolean value.

Example:

<cfset myage = 35>
<cfset myname = "dean">
<CFOUTPUT>
Given Assertion="myage as a: isnumeric(|a|); |a| gt 0; |a| lt 100 ! myname as b: isdefined('|b|'); len(|b|) GT 3":<BR>
<cfif assert("myage as a: isnumeric(|a|); |a| gt 0; |a| lt 100 ! myname as b: isdefined('|b|'); len(|b|) GT 3")>

Assertion  is correct
<cfelse>
Assertion is incorrect
</cfif>
</CFOUTPUT>

Parameters:

Full UDF Source:

<cfscript>
/**
 * Complex variable checking with a single function call.
 * Version 2 by Michael Wolfe, &#109;&#105;&#107;&#101;&#121;&#64;&#109;&#105;&#107;&#101;&#121;&#99;&#101;&#110;&#116;&#114;&#97;&#108;&#46;&#99;&#111;&#109;. Returns false earlier.
 * 
 * @param assertion 	 Assertion rule string you want to validate against.  Variable names should be delimited by the pipe (|). (Required)
 * @return Returns a Boolean value. 
 * @author Dean Chalk (&#109;&#105;&#107;&#101;&#121;&#64;&#109;&#105;&#107;&#101;&#121;&#99;&#101;&#110;&#116;&#114;&#97;&#108;&#46;&#99;&#111;&#109;&#100;&#99;&#104;&#97;&#108;&#107;&#57;&#57;&#64;&#104;&#111;&#116;&#109;&#97;&#105;&#108;&#46;&#99;&#111;&#109;) 
 * @version 2, September 23, 2004 
 */
function assert(assertion) {
	var result = 1;
	var loopvar1 = 0;
	var loopvar2 = 0;
	var variableassertion = "";
	var varsection = "";
	var varname = "";
	var varalias = "";
	var assertionsection = "";
	var anassertion = "";
	var assertnow = "";
	var doBreak = false;
	
	for(loopvar1 = 1; loopvar1 LTE listlen(assertion, "!"); loopvar1 = incrementvalue(loopvar1)) {
		variableassertion = listgetat(assertion, loopvar1, "!");
		varsection = trim(gettoken(variableassertion, 1, ":"));
		varname = trim(listfirst(varsection, " "));
		varalias = trim(listlast(varsection, " "));
		assertionsection = trim(gettoken(variableassertion, 2, ":"));
		
		for(loopvar2 = 1; loopvar2 LTE listlen(assertionsection, ";"); loopvar2 = incrementvalue(loopvar2)) {
			anassertion = listgetat(assertionsection, loopvar2, ";");
			
			if(not isdefined(varname)){
				result = 0;
				doBreak = true;
				break;
			} else {
				assertnow = replacenocase(anassertion, "|#varalias#|", varname, "ALL");
				
				if(not(evaluate(trim(assertnow)))){
					result = 0;
					doBreak = true;
					break;
				}
			}
		}
		
		if(doBreak){
			break;
		}
	}
	
	return result;
}
</cfscript>