CFLib.org – getStackTrace

getStackTrace()

Last updated January 26, 2004

Download UDF

author

Ivo D. SIlva
Send Email

Version: 1 | Requires: ColdFusion MX | Library: UtilityLib

Rated 0 time(s). Average Rating: 0

Description:
Gets the current stack trace, even if no error was thrown, and returns it in a query.

Return Values:
Returns a query.

Example:

Parameters:

No arguments.

Full UDF Source:

	
	<cfscript>
/**
 * Gets the current stack trace, even if no error was thrown, and returns it in a query.
 * 
 * @return Returns a query. 
 * @author Ivo D. SIlva (aphex@netvisao.pt) 
 * @version 1, January 26, 2004 
 */
function getStackTrace() {
  var j = "";
  var i = "";
  var e = "";
  var StackTrace = "";
  
  try
  {
    j = CreateObject("java","java.lang.Throwable");
    j = j.getStackTrace();

    StackTrace = QueryNew("ClassName,MethodName,NativeMethod,LineNumber,hashCode");
    QueryAddRow(StackTrace,ArrayLen(j));
  
    for (i=1; i le ArrayLen(j); i = i+1)
    {
      QuerySetCell(StackTrace,'ClassName',j[i].getClassName(),i);
      QuerySetCell(StackTrace,'MethodName',j[i].getMethodName(),i);
      QuerySetCell(StackTrace,'NativeMethod',j[i].isNativeMethod(),i);
      QuerySetCell(StackTrace,'LineNumber',j[i].getLineNumber(),i);
      QuerySetCell(StackTrace,'hashCode',j[i].hashCode(),i);
    }
  }
  catch ( any e )
  {
    return e;
  }
  
  return StackTrace;
}
</cfscript>